[morgan1991]

amel27, спасибо помогло.
Дальше сделал так:

Код:

$ExtraPuTTY = EnvGet("ExtraPuTTY") ; путь к программе
$thConn = DllStructCreate("ulong") ; структура описателя соединения
If $ExtraPuTTY == "" Then MsgBox(16, "Script Error!", "Переменная окружения ExtraPuTTY не задана!")
; Открываем DLL
$hDll = DllOpen($ExtraPuTTY & "\ExtraPuTTY.dll")
If $hDll=-1 Then MsgBox(16, "Script Error!", "Файл ExtraPuTTY.DLL не найден!")
; Подключаемся...
$aRet = DllCall($hDll, "int", "Connexion", _
    "str", "94.100.177.6", _           ; TargetName (TargetName or PuttySession Name )
    "ptr", DllStructGetPtr($thConn), _ ; ConnexionId (Connexion Handle)
    "str", "", _                       ; Login
    "str", "", _                       ; Password
    "int", 0, _                        ; ShowPuTTY (TRUE: Putty Terminal is display, FALSE: not display)
    "int", 0, _                        ; Protocol (0:Telnet,1:SSH,2:Rlogin,3:Raw,4:LoadPutty Session)
    "int", 110, _                      ; PortNumber (If the parameter is set to 0, the value of the default settings of putty is used)
    "int", 0, _                        ; GenerateReport (1:extraputty report activate,0:Not activate)
    "ptr", 0 )                         ; CallBackRcvData
; Анализируем результат
If @error Then MsgBox(16, "DllCall Error!", @error &":"& @extended)
$hConn = DllStructGetData($thConn, 1) ; Получаем описатель соединения
ConsoleWrite("Результат выполнения ф-ции Connexion = "& $aRet[0] &@CRLF)

$aRet2 = DllCall($hDll, "int", "SendRcvData", _
    "ptr", DllStructGetPtr($thConn), _
    "str", "USER ЛОГИН", _
    "int", 1, _
    "str", "com", _
    "int", 1000, _
    "int", 1, _
    "int", 2048, _
    "int", 0)
ConsoleWrite("Результат выполнения ф-ции SendRcvData = "& $aRet2[0] &@CRLF)

; Закрываем соединение
If $hConn <> 0 Then
    DllCall($hDll, "int", "CloseConnexion", "ulong", $hConn)
EndIf

А в ответ:

Результат выполнения ф-ции Connexion = 0 Результат выполнения ф-ции SendRcvData = 1

Что опять не так?

[amel27]

Что опять не так? »

путаешь указатели с данными

Код:

$ExtraPuTTY = EnvGet("ExtraPuTTY") ; путь к программе
$thConn = DllStructCreate("ulong") ; структура описателя соединения
If $ExtraPuTTY == "" Then Exit MsgBox(16, "Script Error!", "Переменная окружения ExtraPuTTY не задана!")
$hDll = DllOpen($ExtraPuTTY & "\ExtraPuTTY.dll")
If $hDll=-1 Then Exit MsgBox(16, "Script Error!", "Файл ExtraPuTTY.DLL не найден!")

$aRet = DllCall($hDll, "int", "Connexion", _
    "str", "94.100.177.6", "ptr", DllStructGetPtr($thConn), _
    "str", "", "str", "", "int", 0, _
    "int", 0, "int", 110, _
    "int", 0, "ptr", 0 )
If @error Then MsgBox(16, "DllCall Error!", @error &":"& @extended)
$hConn = DllStructGetData($thConn, 1) ; Получаем описатель соединения
ConsoleWrite("Результат выполнения ф-ции Connexion = "& $aRet[0] &@CRLF)

$iMax = 1024                                          ; размер буфера
$tBuf = DllStructCreate("char["& $iMax &"]")          ; буфер
$tpBuf = DllStructCreate("ptr")                       ; указатель на буфер
DllStructSetData($tpBuf, 1, DllStructGetPtr($tBuf))   ; устанавливаем указатель

$aRet = DllCall($hDll, "int", "SendRcvData", _
    "ulong", $hConn, "str", "USER ivan@mybox.ru", _
    "str", "", "str", "", "long", 1000, _
    "int", DllStructGetPtr($tpBuf), "int", $iMax, _
    "int", 0)
ConsoleWrite("Результат выполнения ф-ции SendRcvData = "& $aRet[0] &@CRLF)
ConsoleWrite("Содержимое буфера:"& DllStructGetData($tBuf,1) &@CRLF)

; Закрываем соединение
If $hConn <> 0 Then
    DllCall($hDll, "int", "CloseConnexion", "ulong", $hConn)
EndIf

З.Ы. в комплекте идет скомпиленый пример "SampleConnexion.exe" - полезная тулза для ручной установки соединения и проверки всех TELNET-команд

[got686]

Спасибо автору. Он сделал все совершенно верно в изначальном коде и без сторонних утилит. Я тоже убил сутки на раскрычивание этого дела, а стоило прочитать спецификацию pop3. Каждая команда оканчивается символом CRLF (перенос каретки).

Изначальный код верен с добавлением этого символа