inco1,
Для обеих функций результат будет иметь минимум три значения - да, нет, ошибка/не_знаю
В случае NetGetJoinInformation полноценный вариант в виде макроса будет выглядеть так:
NetGetJoinInformation macro
Код:
/* NetGetJoinInformation macro
Retrieves join status information for the specified computer
Usage:
${NetGetJoinInformation} in_computerName out_joinToName out_joinStatus
Parameters:
in_computerName - DNS or NetBIOS name of the computer on which to call the function.
If this parameter is '' or -, the local computer is used.
out_joinToName - NetBIOS name of the domain or workgroup to which the computer is joined
If this parameter is '' or -, the value is not used.
out_joinStatus - Join status of the specified computer:
success:
0 = NetSetupUnknownStatus
1 = NetSetupUnjoined
2 = NetSetupWorkgroupName
3 = NetSetupDomainName
failure:
-SYSTEM_ERROR_CODE, e.g. -53 == ERROR_BAD_NETPATH (53)
https://learn.microsoft.com/en-us/windows/win32/debug/system-error-codes--0-499-
https://learn.microsoft.com/en-gb/windows/win32/api/lmjoin/nf-lmjoin-netgetjoininformation
*/
!define NetGetJoinInformation `!insertmacro NetGetJoinInformation `
!macro NetGetJoinInformation in_computerName out_joinToName out_joinStatus
!if '${in_computerName}' == '-'
Push ''
!else
Push '${in_computerName}'
!endif
Exch $0
Push $1
Push $2
System::Call '*(i)p.r1'
System::Call 'netapi32::NetGetJoinInformation(t r0, @ r2, p r1)i.r0'
!if '${out_joinToName}' == ''
!define /redef out_joinToName -
!endif
!if ${out_joinToName} != '-'
!define NetGetJoinInformation[jmp] +5
!else
!define NetGetJoinInformation[jmp] +4
!endif
StrCmp $0 0 0 ${NetGetJoinInformation[jmp]}
;ok
System::Call '*$1(i.r0)' ; get status
System::Free $1
!if ${out_joinToName} != '-'
System::Call '*$2(t.r1)' ; get name
!endif
Goto +3
;not ok
StrCpy $0 -$0 ; -SYSTEM_ERROR_CODE
StrCpy $1 ''
!undef NetGetJoinInformation[jmp]
StrCmp $2 0 +2
System::Call "netapi32::NetApiBufferFree(pr2)"
Pop $2
!if ${out_joinToName} != '-'
Exch $1 ; name
Pop ${out_joinToName}
!else
Pop $1
!endif
Exch $0
Pop ${out_joinStatus}
!macroend
Для локальной машины ${NetGetJoinInformation} '' '' $R0 или ${NetGetJoinInformation} - - $R0
запишет в $R0 результат:
- Отрицательный результат = ошибка
- Неотрицательный результат:
3 = однозначно в домене
1,2 = однозначно не в домене
0 = неизвестно
В простейшем случае, когда (однозначно в домене == Да, в остальных случаях == Нет), можно добавить LogicLib-тест
Код:
!define IsInDomain `"" IsInDomain`
!macro _IsInDomain _a _b _t _f
!insertmacro _LOGICLIB_TEMP
${NetGetJoinInformation} `${_b}` - $_LOGICLIB_TEMP
StrCmp $_LOGICLIB_TEMP 3 `${_t}` `${_f}`
!macroend
Тогда проверочное выражение сократится до
Код:
${If} ${IsInDomain} ''
DetailPrint 'in domain'
${Else}
DetailPrint 'not in domain'
${EndIf}
