.: NSIS

iglezz · Отправлено: **18:41, 01-06-2023** | #**2731**

AlekseyPopovv,
В первом случае сложностей не вижу
Во втором случае вижу пару особенностей в виде необходимости получения SID и преобразования буквы диска в имя устройства

Для получения SID текущено пользователя можно применить макрос GetCurrentUserSID

GetCurrentUserSID

Код:

!define GetCurrentUserSID `!insertmacro GetCurrentUserSID `
!macro GetCurrentUserSID out_SID
  Push $0 ; fn ret / out_SID
  Push $1 ; SID struct
  Push $2 ; tmp
  
  System::Call "advapi32::GetUserName(t.s, *i${NSIS_MAX_STRLEN}) i.r0"
  StrCmp $0 0 +5
  System::Call 'advapi32::LookupAccountName(i0, ts, @r1, *i${NSIS_MAX_STRLEN}, t .r2, *i ${NSIS_MAX_STRLEN}, *i .r2 ) i.r0'
  StrCmp $0 0 +3
  System::Call 'advapi32::ConvertSidToStringSid(pr1, *t.r0 )'
  Goto +2
  StrCpy $0 ''
  
  Pop $2
  Pop $1
  Exch $0

  Pop ${out_SID}
!macroend

Пример использования:

Код:

${GetCurrentUserSID} $0
DetailPrint 'SID = [$0]'

Если надо пройтись по всем пользователям, то можно использовать макрос ~~EnumUsersReg~~ EnumUsersRegEx (пример).

Для преобразования пути в простейшем случае (c:\path -> \Device\HarddiskVolume3\path) можно использовать такой макрос:

Скрытый текст

Код:

!define GetPathWithDeviceName `!insertmacro GetPathWithDeviceName `
!macro GetPathWithDeviceName out_DevPath in_DOSPath
  Push '${in_DOSPath}'
  Exch $0
  Push $1
  Push $2

  StrLen $1 $0
  StrCmp $1 1 0 +3
    StrCpy $1 $0:
    Goto +2

  StrCpy $1 $0 2
  System::Call 'kernel32::QueryDosDevice(tr1, t.r2, i${NSIS_MAX_STRLEN} ) i.r3'
  
  StrCmp $3 0 0 +3
    StrCpy $0 ''
    Goto +3

  StrCpy $0 $0 '' 2
  StrCpy $0 $2$0

  Pop $2
  Pop $1
  Exch $0

  Pop ${out_DevPath}
!macroend

Пример использования:

Код:

${GetPathWithDeviceName} $0 "C:\path\to\file"
DetailPrint 'path = [$0]'

AlekseyPopovv · Конфигурация компьютера

Как покрасить эти места в белый?

Код:

Function MyGUIInit
System::Call "user32::GetWindowLong(i$HWNDPARENT,i-20)i.s"
System::Int64Op "0x80000" |
System::Call "user32::SetWindowLong(i$HWNDPARENT,i-20,is)"
System::Call "user32::SetLayeredWindowAttributes(i$HWNDPARENT,i,i243,i0x00000002)"

GetDlgItem $R0 $HWNDPARENT 1034
GetDlgItem $R1 $HWNDPARENT 1037
GetDlgItem $R2 $HWNDPARENT 1038
SetCtlColors $R0 000000 FFFFFF
SetCtlColors $R1 000000 FFFFFF
SetCtlColors $R2 000000 FFFFFF
FunctionEnd

iglezz · Отправлено: **20:59, 02-06-2023** | #**2733**

Кроме замены цвета фона окна (в .onGUIInit) надо ещё поменять цвет фона каждой страницы и всех элементов в ней (в show-функции для каждой страницы)

пример

Код:

!include WinMessages.nsh
RequestExecutionLevel user
InstallDir $TEMP

Page components "" cshow
Page directory "" dshow
Page instfiles "" ishow

; define background color
!define BACKGROUNDCOLOR 0xFFFFFF

Section `Dummy Section`
    DetailPrint ...
SectionEnd

Function cshow
    ; repaint page
    FindWindow $1 "#32770" "" $HWNDPARENT
    SetCtlColors $1 '' ${BACKGROUNDCOLOR}
    
    ; repaint page controls
    GetDlgItem $0 $1 1031
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1006
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1017
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1021
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1022
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1023
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1032
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
FunctionEnd

Function dshow
    ; repaint page
    FindWindow $1 "#32770" "" $HWNDPARENT
    SetCtlColors $1 '' ${BACKGROUNDCOLOR}

    ; repaint page controls
    GetDlgItem $0 $1 1031
    SetCtlColors $0 '' ${BACKGROUNDCOLOR} 
    GetDlgItem $0 $1 1006
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1019
    SetCtlColors $0 '' ${BACKGROUNDCOLOR} 
    ; ...
FunctionEnd

Function ishow
    ; repaint page
    FindWindow $1 "#32770" "" $HWNDPARENT
    SetCtlColors $1 '' ${BACKGROUNDCOLOR}

    ; repaint page controls
    GetDlgItem $0 $1 1031
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1006
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
FunctionEnd

Function .onGUIInit
    ; repaint window
    SetCtlColors $HWNDPARENT '' ${BACKGROUNDCOLOR}

    ; set BrandingText ${BACKGROUNDCOLOR} background
    GetDlgItem $0 $HWNDPARENT 1028
    SetCtlColors $0 '' transparent
FunctionEnd

iglezz · Отправлено: **21:31, 02-06-2023** | #**2734**

Фон также можно задавать для каждой отдельной страницы

пример

Код:

!include WinMessages.nsh
RequestExecutionLevel user
InstallDir $TEMP

Page components "" cshow
Page directory "" dshow
Page instfiles "" ishow

!define /ifndef RDW_INVALIDATE 0x0001
!define /ifndef RDW_ERASE      0x0004

; define background color
!define BACKGROUNDCOLOR 0xFFFFFF

Section `Dummy Section`
    DetailPrint ...
SectionEnd


Function cshow
    ; repaint window
    SetCtlColors $HWNDPARENT '' ${BACKGROUNDCOLOR}

    ; repaint page
    FindWindow $1 "#32770" "" $HWNDPARENT
    SetCtlColors $1 '' ${BACKGROUNDCOLOR}
    
    ; repaint page controls
    GetDlgItem $0 $1 1031
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1006
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1017
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1021
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1022
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1023
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1032
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}

    System::Call "user32::RedrawWindow(i,i,i,i)i ($HWNDPARENT, 0, 0,${RDW_INVALIDATE}|${RDW_ERASE})"
FunctionEnd

Function dshow
    ; redefine page background
    !define /redef BACKGROUNDCOLOR 0x88ff88

    ; repaint window
    SetCtlColors $HWNDPARENT '' ${BACKGROUNDCOLOR}

    ; repaint page
    FindWindow $1 "#32770" "" $HWNDPARENT
    SetCtlColors $1 '' ${BACKGROUNDCOLOR}

    ; repaint page controls
    GetDlgItem $0 $1 1031
    SetCtlColors $0 '' ${BACKGROUNDCOLOR} 
    GetDlgItem $0 $1 1006
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1019
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1020
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1023
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1024
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}

    System::Call "user32::RedrawWindow(i,i,i,i)i ($HWNDPARENT, 0, 0,${RDW_INVALIDATE}|${RDW_ERASE})"
FunctionEnd

Function ishow
    ; redefine page background
    !define /redef BACKGROUNDCOLOR 0xabcdef

    ; repaint window
    SetCtlColors $HWNDPARENT '' ${BACKGROUNDCOLOR}

    ; repaint page
    FindWindow $1 "#32770" "" $HWNDPARENT
    SetCtlColors $1 '' ${BACKGROUNDCOLOR}

    ; repaint page controls
    GetDlgItem $0 $1 1031
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}
    GetDlgItem $0 $1 1006
    SetCtlColors $0 '' ${BACKGROUNDCOLOR}

    System::Call "user32::RedrawWindow(i,i,i,i)i ($HWNDPARENT, 0, 0,${RDW_INVALIDATE}|${RDW_ERASE})"
FunctionEnd


Function .onGUIInit
    ; set BrandingText${BACKGROUNDCOLOR} background
    GetDlgItem $0 $HWNDPARENT 1028
    SetCtlColors $0 '' transparent
FunctionEnd

AlekseyPopovv · Конфигурация компьютера

Как переименовать кнопку отмена на кастомной странице ReadmePage?

iglezz · Отправлено: **19:33, 03-06-2023** | #**2736**

Пример прямо в справке есть

Код:

GetDlgItem $1 $HWNDPARENT 2
SendMessage $1 ${WM_SETTEXT} 0 "STR:Goodbye"

id кнопок:
1 = next
2 = cancel
3 = back

AlekseyPopovv · Конфигурация компьютера

Есть у кого ни будь пример кастомной страницы MUI_PAGE_INSTFILES?

AlekseyPopovv · Конфигурация компьютера

Как убрать кнопку закрыть и сделать кнопку отмена активной?

iglezz · Отправлено: **00:45, 05-06-2023** | #**2739**

Цитата AlekseyPopovv:

Как убрать кнопку закрыть и сделать кнопку отмена активной? »

Инструкция ShowWindow с примером в справке, аналогично переименовыванию.
Отмену активной сделать мало, там ещё много чего написать надо для обработки этой отмены - InstFiles Cancel - Allowing a user to cancel installation during InstFiles

AlekseyPopovv · Конфигурация компьютера

iglezz, как поменять шрифт над прогресс баром?