[MKN]

вся сложность загоняется под коврик »

Это я понимаю. И это не только в программировании... И это наверное не есть хорошо... Хотя потребителю пофиг...

[inco1]

iglezz,

Менять в hostsblock.nsh ничего не надо.

Я сразу даже не понял, что это для любых расширений и полез изменять.
Даже адреса с 127.0.0.1 не пропускаются, а бекапятся и записываются как 0.0.0.0
Отступы и пробелы так же четко отрабатываются и не дублируются.
Дааа..., код в несколько строчек для качественной правки HOSTS это нечто.
Теперь понятно, сколько вложено труда в hostsblock.nsh.

MKN, Так же огромная благодарность за отклик и проделанную работу. Но работа iglezz - шедевр.

[iglezz]

MKN, inco1,
В качестве замечания, на будущее и для лучшего понимания.

${LineRead} В подобных циклах - штука дико неэффективная. Алгоритм маляра Шлемиеля, как шутят.
Для N-ой по номеру строки будет сделана куча работы - FileOpen, N FileRead'ов, FileClose, счётчики и проверки

Простейший цикл последовательного чтения файла:

Код:

    FileOpen $handle $filename R
    ${Do} 
        FileRead $handle $fileread
        ${IfThen} ${Errors} ${|} ${ExitDo} ${|}

        DetailPrint '[$fileread]'
    ${Loop}
    FileClose $handle

[inco1]

iglezz,
Проверил множество раз. Ваш предложенный компактный вариант не работает, если файла hosts.ics не существует. Точнее сказать работает, но добавляет только четыре строки без первой.
Если же файл hosts.ics уже существует, то работает правильно. как и задумано. Проверял самым простым экзешником:

Скрытый текст

Код:

Unicode true
SetOverwrite on
RequestExecutionLevel admin

!include "x64.nsh"
!include "LogicLib.nsh"
!include "hostsblock.nsh"

Section
    ${IfThen} ${RunningX64} ${|} ${DisableX64FSRedirection} ${|}
    
    Var /global hostsfile
    StrCpy $hostsfile "$SYSDIR\drivers\etc\hosts.ics"

    ${IfNot} ${FileExists} $hostsfile
        FileOpen  $0 $hostsfile W
        FileClose $0
    ${EndIf}

    SetFileAttributes $hostsfile NORMAL

    ${hostsfile_BlockHost} $hostsfile 'martau.com'
    ${hostsfile_BlockHost} $hostsfile 'www.martau.com'
    ${hostsfile_BlockHost} $hostsfile 'www.total-uninstall.com'
    ${hostsfile_BlockHost} $hostsfile 'total-uninstall.com'
    ${hostsfile_BlockHost} $hostsfile '64.91.254.118'

    SetFileAttributes $hostsfile READONLY
SectionEnd

Тот, что я предложил с лишними записями работает как надо, и когда файл hosts.ics отсутствует и когда он уже есть:

Скрытый текст

Код:

Unicode true
SetOverwrite on
RequestExecutionLevel admin

!include "x64.nsh"
!include "LogicLib.nsh"
!include "hostsblock.nsh"

Section
Var /global hostsics
    StrCpy $hostsics "$SYSDIR\drivers\etc"
${IfThen} ${RunningX64} ${|} ${DisableX64FSRedirection} ${|}
${If} ${FileExists} "$hostsics\hosts.ics"
    SetFileAttributes "$hostsics\hosts.ics" NORMAL
    StrCpy $0 '$hostsics\hosts.ics'
    StrCpy $1 '$hostsics\1.txt'
    StrCpy $2 '$hostsics\2.txt'
    CopyFiles /SILENT $0 $1
    FileOpen  $3 $1 A
    FileSeek  $3 0 END
    FileClose $3
    CopyFiles /SILENT $1 $2
    FileOpen $3 $2 A
    FileClose $3
    ${hostsfile_BlockHost} $2 'martau.com'
    ${hostsfile_BlockHost} $2 'www.martau.com'
    ${hostsfile_BlockHost} $2 'www.total-uninstall.com'
    ${hostsfile_BlockHost} $2 'total-uninstall.com'
    ${hostsfile_BlockHost} $2 '64.91.254.118'
    CopyFiles /SILENT $2 $0
    Delete "$hostsics\1.txt"
    Delete "$hostsics\2.txt"
${Else}
    FileOpen $0 "$hostsics\hosts.ics" w
    FileWrite $0 "0.0.0.0 martau.com $\r$\n"
    FileWrite $0 "0.0.0.0 www.martau.com $\r$\n"
    FileWrite $0 "0.0.0.0 total-uninstall.com $\r$\n"
    FileWrite $0 "0.0.0.0 www.total-uninstall.com $\r$\n"
    FileWrite $0 "0.0.0.0 64.91.254.118 $\r$\n"
    FileClose $0
${EndIf}
    SetFileAttributes "$hostsics\hosts.ics" READONLY
SectionEnd

Так же правильно работает, как с уже созданным файлом "hosts.ics", так и без него такой вариант:

Скрытый текст

Код:

Unicode true
SetOverwrite on
RequestExecutionLevel admin
!include "x64.nsh"
!include "LogicLib.nsh"
!include "hostsblock.nsh"
Section
Var /global hostsfile
    StrCpy $hostsfile "$SYSDIR\drivers\etc\hosts.ics"
${IfThen} ${RunningX64} ${|} ${DisableX64FSRedirection} ${|}
${If} ${FileExists} "$hostsfile"
    SetFileAttributes "$hostsfile" NORMAL
    ${hostsfile_BlockHost} "$hostsfile" 'martau.com'
    ${hostsfile_BlockHost} "$hostsfile" 'www.martau.com'
    ${hostsfile_BlockHost} "$hostsfile" 'www.total-uninstall.com'
    ${hostsfile_BlockHost} "$hostsfile" 'total-uninstall.com'
    ${hostsfile_BlockHost} "$hostsfile" '64.91.254.118'
${Else}
    FileOpen $0 "$hostsfile" w
    FileWrite $0 "0.0.0.0 martau.com $\r$\n"
    FileWrite $0 "0.0.0.0 www.martau.com $\r$\n"
    FileWrite $0 "0.0.0.0 total-uninstall.com $\r$\n"
    FileWrite $0 "0.0.0.0 www.total-uninstall.com $\r$\n"
    FileWrite $0 "0.0.0.0 64.91.254.118 $\r$\n"
    FileClose $0
${EndIf}
    SetFileAttributes "$hostsfile" READONLY
SectionEnd

[iglezz]

inco1, Файл исправлен по старой ссылке.
Косяков там на самом деле там было больше..

[inco1]

iglezz, Огромнейшая благодарность.
Теперь код, практически в семь строчек работает четко,красиво и правильно, и лучше, чем код в семьдесят строк из "справки", которую всем в свое время навязывал K.A.V. Ему было пытались объяснить, что его код с hosts не корректно работает, но в ответ было, типа "сам дурак, учи справку".

[MKN]

Задача: нужна кастомная страница, на которой, к примеру, вверху страницы помещаются несколько кликабельных либо кнопок, либо текст-заголовков, не суть.
При клике на кнопке-заголовке - раскрывается соответствующий список с чекбоксами.
При клике на другой кнопке-заголовке - предыдущий список закрывается, а новый открывается.
Ессно запоминается состояние чекбоксов, иходя из которого применяются действия...

Список с чекбоксами позволяет сделать плагин ListView. Но возможно ли сделать несколько раскрывающихся списков на кастомной странице ?

И ещё, можно ли, имея статичную часть окна на странице с кликабельными заголовками, раскрывать списки с чекбоксами в виде других вновь созданных собственных окон с разными элементами в них ? (Совершенно не ясно, как в NSIS можно на одной странице переключать разные окна, при этом сохраняя статично-видимую часть окна откуда осуществляется переключение...)

[iglezz]

Задача: нужна кастомная страница, на которой, к примеру, вверху страницы помещаются несколько кликабельных либо кнопок, либо ...»

В простейшем случае по событию от кнопки или другого контрола показываются нужные вещи и прячутся ненужные. Фактически это имитация (с кучей ручной работы) отсутствующего в nsDialogs Tab Control.
А дальше зависит от потребностей и фантазии..

пример

Код:

RequestExecutionLevel user
!include "LogicLib.nsh"
!include "nsDialogs.nsh"

Page custom NSD

Section 
SectionEnd

Var Dialog
Var hButtonOpt1
Var hButtonOpt11
Var hButtonOpt12
Var hButtonOpt13
Var hButtonOpt2
Var hButtonOpt21
Var hButtonOpt22
Var hButtonOpt3
Var hButtonOpt31
Var hButtonOpt32

Function NSD
	nsDialogs::Create 1018
	Pop $Dialog
    
    
    ${NSD_CreateFirstRadioButton} 0u 0u 30% 16u "Options 1"
    Pop $hButtonOpt1
    ${NSD_OnClick} $hButtonOpt1 SwitchOptions

    ${NSD_CreateAdditionalRadioButton} 33% 0u 30% 16u "Options 2"
    Pop $hButtonOpt2
    ${NSD_OnClick} $hButtonOpt2 SwitchOptions

    ${NSD_CreateAdditionalRadioButton} 66% 0u 30% 16u "Options 3"
    Pop $hButtonOpt3
    ${NSD_OnClick} $hButtonOpt3 SwitchOptions


    ${NSD_CreateCheckBox} 10u 30u 80u 20u "111"
    Pop $hButtonOpt11
    ${NSD_AddStyle} $hButtonOpt11 ${WS_GROUP}
    ${NSD_CreateCheckBox} 10u 50u 80u 20u "222"
    Pop $hButtonOpt12
    ${NSD_CreateCheckBox} 10u 70u -20u 20u "333"
    Pop $hButtonOpt13

    ${NSD_CreateCheckBox} 10u 30u -20u 20u "2x111"
    Pop $hButtonOpt21
    ${NSD_CreateCheckBox} 10u 50u -20u 20u "2x222"
    Pop $hButtonOpt22

    ${NSD_CreateCheckBox} 10u 30u -20u 20u "3x111"
    Pop $hButtonOpt31
    ${NSD_CreateCheckBox} 10u 50u -20u 20u "3x222"
    Pop $hButtonOpt32

    SendMessage $hButtonOpt1 ${BM_CLICK} 0 0

    nsDialogs::Show
FunctionEnd


Function SwitchOptions
    Pop $0

    ${Select} $0
        ${Case} $hButtonOpt1
            StrCpy $1 ${SW_SHOW}
            StrCpy $2 ${SW_HIDE}
            StrCpy $3 ${SW_HIDE}
        ${Case} $hButtonOpt2
            StrCpy $1 ${SW_HIDE}
            StrCpy $2 ${SW_SHOW}
            StrCpy $3 ${SW_HIDE}
        ${Case} $hButtonOpt3
            StrCpy $1 ${SW_HIDE}
            StrCpy $2 ${SW_HIDE}
            StrCpy $3 ${SW_SHOW}
    ${EndSelect}

    ShowWindow $hButtonOpt11 $1
    ShowWindow $hButtonOpt12 $1
    ShowWindow $hButtonOpt13 $1

    ShowWindow $hButtonOpt21 $2
    ShowWindow $hButtonOpt22 $2

    ShowWindow $hButtonOpt31 $3
    ShowWindow $hButtonOpt32 $3
FunctionEnd

[MKN]

iglezz,
Такой способ понятен, но списки хотелось бы выпадающие, а не пропадающие...
Если всё же использовать несколько ListView размером во всю страницу, их получится переключать(скрывать) без проблем ? Они ведь будут друг на друге... И запомниться ли состояние выбранных элементов в LV при переключении ?

[iglezz]

MKN, А тут всё равно какой контент будет. Хоть Listview, хоть RichText, хоть видео...
На состояние контролов это не повлияет- они просто прячутся/показываются.