[inco1]

Всем доброго времени суток.
Столкнулся с двумя проблемами.
В папке $WINDIR\System32\drivers\ хочу удалить файл .sys. В семерке этот файл спокойно удаляется с помощью макроса и команды:

Скрытый текст

Код:

!insertmacro DisableX64FSRedirection
Delete "$WINDIR\System32\drivers\test.sys"
!insertmacro EnableX64FSRedirection

В десятке почему то не удаляется. Когда начал пробовать в десятке удалить его вручную, то он пишет, что занят процессом. Но IObit Unlocker показывает, что никаким процессом он не занят и командой "разблокировать и удалить" спокойно его удаляет.
Вот такой вопрос, имеется ли в nsis команда типа "снять все атрибуты, разблокировать и удалить", чтобы удалялся в десятке файл, как это делает IObit Unlocker?
И вторая проблема.
Имеется батник - это вполне рабочий генератор случайного 32 значного кода с записью в нужную область реестра:

Скрытый текст

Код:

@echo off
cls
 
@echo.
@echo.
 
call :randomizeSequence 32 sequence
@echo sequence = '%sequence%'
 
REG ADD HKLM\Software\Test/v TestId /t REG_SZ /d %sequence% /f
 exit /b
 
:randomize
    set MIN=%1
    set MAX=%2
    set /A %3=%MIN% + (%MAX% - %MIN% + 1) * %random% / 32768
exit /b
 
:fillArray
    set "array[%cnt%]=%1"
    set /a cnt +=1
exit /b
 
:initialRandomize
    if defined ALREADYINIT (exit /b)
    set ALREADYINIT=true

    for %%a in ( 1  2  3  4  5  6  7  8  9  a  b  c  d  e  f  g) do (
        call :fillArray %%a  
    )
exit /b
 
:accumulate
    call :randomize 1 15 index
    call set "char=%%array[%index%]%%"
    call set "%dst%=%%%dst%%%%char%"
exit /b
 
:randomizeSequence
    set len=%1
    set dst=%2
    call :initialRandomize
    for /L %%a in (1 1 %len%) do (
        call :accumulate %%a
    )
exit /b

Помогите, пожалуйста сделать то же самое, что в батнике только кодом.

[iglezz]

имеется ли в nsis команда типа "снять все атрибуты, разблокировать и удалить", чтобы удалялся в десятке файл, как это делает IObit Unlocker? »

Нет.
Если "IObit Unlocker показывает, что никаким процессом он не занят и командой "разблокировать и удалить" спокойно его удаляет", то он, скорее всего, чего-то не договаривает (дабы не перегрузить пользователю мозг технической информацией ).

Имеется батник - это вполне рабочий генератор случайного 32 значного кода »

Можно сгенерировать GUID и отфильтровать до [0-9A-F]

Скрытый текст

макрос ${GetRandomHexStringG} OUTPUT LENGTH
Запишет в переменную OUTPUT строку длиной:
LENGTH символов для 1 <= LENGTH <= 32
32 символа для других значений

Код:

!include "Util.nsh"

!define GetRandomHexStringG '!insertmacro GetRandomHexStringG'

!macro GetRandomHexStringG OUTPUT LENGTH
	Push ${LENGTH}
	${CallArtificialFunction} GetRandomHexStringG_
	Pop ${OUTPUT}
!macroend

!macro GetRandomHexStringG_
	Push $0 ; result string 
	Exch
	Exch $1 ; result chars count
	Push $2 ; guid string
	Push $3 ; length of guid string
	Push $4 ; counter
	Push $5 ; temp / char 
	
	StrCpy $0 ''
	System::Call 'ole32::CoCreateGuid(g .r2)'
	StrLen $3 $2
	IntOp $3 $3 - 1 ; to skip last curly bracket
	StrCpy $4 1 ; to skip first curly bracket
	
	Loop:
		IntCmp $4 $3 ExitLoop 0 ExitLoop
		StrCpy $5 $2 1 $4
		
		IntOp $4 $4 + 1
		StrCmp $5 '-' Loop
		
		StrCpy $0 $0$5
		IntOp $1 $1 - 1
		IntCmp $1 0 ExitLoop
		Goto Loop
	ExitLoop:
	
	Pop $5
	Pop $4
	Pop $3
	Pop $2
	Pop $1
	Exch $0
!macroend

пример:

Код:

	${GetRandomHexStringG} $9 10
	DetailPrint "result $9"

[inco1]

iglezz,

Можно сгенерировать GUID и отфильтровать до [0-9A-F]

Я понял, что ничего не понял. Что конкретно нужно прописать в строку добавления в реестр WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Test" "TestId" "?" , чтобы с вашего кода прописывалось 32 значное случайное число?

[iglezz]

inco1,

Код:

${GetRandomHexStringG} $0 32 ; записать сгенерированное значение (32 символа) в $0
WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Test" "TestId" "$0" ; записать $0 в реестр

[inco1]

iglezz, Спасибо, буду пробовать.

PS. Всё отлично работает. Правда буквы заглавные, но это не критично. Спасибо.

[iglezz]

Правда буквы заглавные, но это не критично. »

Вот такой вариант генератора позволяет задавать регистр

Код:

!define GetRandomHexStringRL '!insertmacro GetRandomHexStringR x'
!define GetRandomHexStringRU '!insertmacro GetRandomHexStringR X'

!macro GetRandomHexStringR CASE OUTPUT LENGTH
	Push ${LENGTH}
	Push ${CASE}
	${CallArtificialFunction} GetRandomHexStringR_
	Pop ${OUTPUT}
!macroend

!macro GetRandomHexStringR_
	Exch $0 ; 'x'/'X'
	Exch
	Exch $1 ; length
	Push $2 ; 
	Push $3 ; 
	Push $4 ; 
	Push $5 ; 
	Push $R0 ; CSP handle returned by CryptAcquireContext()
	Push $R1 ; buffer address for data generated by CryptGenRandom()
	
	System::Alloc 32
	Pop $R1
	
	System::Call "advapi32::CryptAcquireContext(*i.R0, i0, i0, i1, i0x40)"
	System::Call "advapi32::CryptGenRandom(iR0, i32, iR1)"
	System::Call "advapi32::CryptReleaseContext(iR0, i0)"
	
	System::Call "*$R1(&i4.r2, &i4.r3, &i4.r4, &i4.r5)"
	System::Free $R0
	
	StrCpy $R0 "%08$0"
	IntFmt $2 $R0 $2
	IntFmt $3 $R0 $3
	IntFmt $4 $R0 $4
	IntFmt $5 $R0 $5
	
	StrCpy $0 $2$3$4$5 $1
	
	Pop $R1
	Pop $R0
	Pop $5
	Pop $4
	Pop $3
	Pop $2
	Pop $1
	Exch $0
!macroend

Пример:

Код:

${GetRandomHexStringRL} $0 32 ; lowercase
${GetRandomHexStringRU} $0 32 ; uppercase

[MKN]

Для генерации стандартного 32 значного GUID, вроде как достаточно :

Код:

OutFile CreateGuid-test.exe
!include "WordFunc.nsh"

Section
System::Call 'OLE32::CoCreateGuid(g.R0)'
${StrFilter} "$R0" "-" "" "" $R1
MessageBox MB_OK "$R1"
SectionEnd

(${StrFilter} из WordFunc.nsh используем для смены регистра)

[inco1]

iglezz,

Вот такой вариант генератора позволяет задавать регистр

Это то. что я хотел. Спасибо.

Рано я обрадовался. Тот первый вариант, что только с верхним регистром отлично вносит 32 знака в реестр и на семерке и на десятке.
Этот вариант с нужным мне нижним регистром вносит 32 знака в реестр только на семерке. На десятке вносит 32 нуля.

MKN, А как я могу прикрутить ваш код , чтобы добавлялось 32 знака из цифр и нижнего регистра в нужную ветку реестра?

[MKN]

inco1,
Очевидно же :

Код:

OutFile CreateGuid-test.exe

Section
System::Call 'OLE32::CoCreateGuid(g.R0)'
MessageBox MB_OK "$R0"
SectionEnd

[inco1]

MKN,
Это вообще не то. Я же выложил батник, он генерирует такой код d2b7daaed38c3532d7d7aa6895fb96ge
iglezz выложил код, который отлично генерит в верхнем регистре 848D8134AB514E70ABE491A6551B5E99
Потом он выложил код с нижним регистром, но который генерит только в семерке, но не хочет генерить в десятке - записывает ноли.
Вы выложили код, который генерит следующее {AE68BE6F-43A2-1FB4-423D-D0C358720163} это не то, что я спрашивал.