[El Sanchez]

Как сделать, чтобы после установки в указанной папке создавался текстовый файл, в который будет выводится список установленных компонентов? »

Kashtan007,

Код:

procedure CurStepChanged(CurStep: TSetupStep);
begin
    case CurStep of
        ssPostInstall:
            SaveStringToFile(ExpandConstant('{app}\components.txt'), WizardSelectedComponents(False), False);
    end;
end;

На скрине видно что строка полностью выделена. »

Dodakaedr, ему не выделять строку надо, а сделать так, чтобы выбрать строку можно было не только по клику мыши по изображению чекбокса/радио, но и по клику по самой строке. WantTabs в True как раз и позволяет такое сделать. Только он не признается куда поделось стандартное свойство WantTabs, может компилятор ругается совсем не на WantTabs, а на что-то другое, только ж ни ругани, ни скрина не представлено.

[Dodakaedr]

но и по клику по самой строке. »

я ж про то же Видео

[El Sanchez]

я ж про то же»

Dodakaedr, diman_21Ru, пардон, ввел всех в заблуждение. Пока сам себя не проверишь, ответа не получишь. Все дело в свойстве TreeViewStyle, которое есть у листа из китайской версии. При значении True (либо в секции Setup директива ComponentsListTVStyle=yes) наблюдаем подобное поведение, WantTabs немного из другой оперы. Для решения проблемы нужно самому обработать мышиные события:

Скрытый текст

Код:

type
    TCheckListBoxHelper = record
        Index: Integer;
        ItemArea: TItemArea;
    end;

var
   CLBHelper: TCheckListBoxHelper;

//////////////////////////////////////////////////////////////////////////////////////////////////////////////
procedure ComponentsListOnMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
    with TNewCheckListBox(Sender) do
    begin
        if (Button = mbLeft) and (CLBHelper.ItemArea = iaItem) and ItemEnabled[CLBHelper.Index] then
        case State[CLBHelper.Index] of
            cbUnchecked,
            cbGrayed:
                CheckItem(CLBHelper.Index, coCheckWithChildren);
            cbChecked:
                CheckItem(CLBHelper.Index, coUncheck);
        end;
    end;
end;

/////////////////////////////////////////////////////////////////////////////////////////////////////////
procedure ComponentsListOnItemMouseMove(Sender: TObject; X, Y: Integer; Index: Integer; Area: TItemArea);
begin
    CLBHelper.Index := Index;
    CLBHelper.ItemArea := Area;
end;

///////////////////////////
procedure InitializeWizard;
begin
    with WizardForm.ComponentsList do
    begin
        if TreeViewStyle then
        begin
            OnMouseDown := @ComponentsListOnMouseDown;
            OnItemMouseMove := @ComponentsListOnItemMouseMove;
        end;
    end;
end;

[diman_21Ru]

El Sanchez, Не помогло (

[nik1967]

El Sanchez, замечательно! Только я позволил себе немного подправить скрипт:

Скрытый текст

Код:

type
    TCheckListBoxHelper = record
        Index: Integer;
        ItemArea: TItemArea;
    end;

var
   CLBHelper: TCheckListBoxHelper;

//////////////////////////////////////////////////////////////////////////////////////////////////////////////
procedure ComponentsListOnMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  if (Button = mbLeft) and (CLBHelper.ItemArea = iaItem) then
  begin
    with TNewCheckListBox(Sender) do
    begin
      if ItemEnabled[CLBHelper.Index] then 
      begin
        case State[CLBHelper.Index] of
          cbUnchecked,
          cbGrayed:
            CheckItem(CLBHelper.Index, coCheckWithChildren);
          cbChecked:
            CheckItem(CLBHelper.Index, coUncheck);
        end;
      end;
    end;
  end;
end;

/////////////////////////////////////////////////////////////////////////////////////////////////////////
procedure ComponentsListOnItemMouseMove(Sender: TObject; X, Y: Integer; Index: Integer; Area: TItemArea);
begin
    CLBHelper.Index := Index;
    CLBHelper.ItemArea := Area;
end;

///////////////////////////
procedure InitializeWizard;
begin
    with WizardForm.ComponentsList do
    begin
        if TreeViewStyle then
        begin
            OnMouseDown := @ComponentsListOnMouseDown;
            OnItemMouseMove := @ComponentsListOnItemMouseMove;
        end;
    end;
end;

а то компоненты, у которых стоит флаг Fixed, тоже были кликабельны.

[diman_21Ru]

Как не крути не работает может кто помочь в личку скину .

nik1967, Поможешь? в личку скину скрипт

[diman_21Ru]

Как снять галочку Filename: "{app}\WoTLauncher.exe"; Description: "Запустить World Of Tanks после установки?"; Flags: postinstall shellexec;

[nik1967]

diman_21Ru, я так понимаю, секция [Run]? Добавь флаг unchecked - в справку заглядывай! И да, проверь личку.

Кстати, как то diman_21Ru задавал вопрос о переключении 3 языков на лету. Переделал пример - сделал его с комбобоксом - теперь языки можно переключать не по кругу, а выборочно. Может кому пригодится.
ЭТО ТОЛЬКО ПРИМЕР! Что бы переключение происходило для всех надписей - все эти надписи нужно переделать!

Скрытый текст

Код:

[setup]
AppName=My Application
AppVersion=1.5
DefaultDirName={pf}
;ShowLanguageDialog=auto

[Languages]
Name: "eng"; MessagesFile: "compiler:Languages\English.isl"
Name: "rus"; MessagesFile: "compiler:Languages\Russian.isl"
Name: "ukr"; MessagesFile: "compiler:Languages\Ukrainian.isl"

[CustomMessages]
; Русский
rusButtonBack=< &Назад
rusButtonNext=&Далее >
rusButtonCancel=Отмена
rusSetupWindowTitle=Установка — %1
rusWelcomeLabel1=Вас приветствует Мастер установки %1
rusWelcomeLabel2=Программа установит %1, версия %2 на Ваш компьютер.%n%nРекомендуется закрыть все прочие приложения перед тем, как продолжить.%n%nНажмите «Далее», чтобы продолжить, или «Отмена», чтобы выйти из программы установки.

; English
engButtonBack=< &Back
engButtonNext=&Next >
engButtonCancel=Cancel
engSetupWindowTitle=Setup — %1
engWelcomeLabel1=Welcome to the %1 Setup Wizard
engWelcomeLabel2=This will install %1 version %2 on your computer.%n%nIt is recommended that you close all other applications before continuing.%n%nClick Next to continue, or Cancel to exit Setup.

; Ukrainian
ukrButtonBack=< &Назад
ukrButtonNext=&Далi >
ukrButtonCancel=Cкасування
ukrSetupWindowTitle=Встановити — %1
ukrWelcomeLabel1=Вас вітає Майстер установки %1
ukrWelcomeLabel2=Програма встановить %1, версія %2 на Ваш комп'ютер.%n%nРекомендуємо закрити всі інші програми перед тим, як продовжити.%n%nНатисніть «Далі», щоб продовжити, або «Скасувати», щоб вийти з програми установки.

[Code]
var
  lang: String;
  ComboBox1: TNewComboBox;

procedure ChangeLang();
begin
  WizardForm.BackButton.Caption:= CustomMessage(lang+'ButtonBack');
  WizardForm.NextButton.Caption:= CustomMessage(lang+'ButtonNext');
  WizardForm.CancelButton.Caption:= CustomMessage(lang+'ButtonCancel');
  WizardForm.Caption:= FmtMessage(CustomMessage(lang+'SetupWindowTitle'), ['{#SetupSetting('AppName')}']);
  WizardForm.WelcomeLabel1.Caption:= FmtMessage(CustomMessage(lang+'WelcomeLabel1'), ['{#SetupSetting('AppName')}']);
  WizardForm.WelcomeLabel2.Caption:= FmtMessage(CustomMessage(lang+'WelcomeLabel2'), ['{#SetupSetting('AppName')}', '{#SetupSetting('AppVersion')}']);
end;

procedure ComboBox1OnChange(Sender: TObject);
begin
  case TNewComboBox(Sender).ItemIndex of
    0: lang:= 'rus';
    1: lang:= 'eng';
    2: lang:= 'ukr';
  end;
    ChangeLang();
end;

procedure InitializeWizard;
begin
  ComboBox1:= TNewComboBox.Create(WizardForm);
  with ComboBox1 do begin
    Parent:= WizardForm;
    Style:= csDropDownList;
    SetBounds(ScaleX(10),WizardForm.CancelButton.Top,WizardForm.CancelButton.Width,WizardForm.CancelButton.Height);
    OnChange:= @ComboBox1OnChange;
    Items.Add('Русский');
    Items.Add('English');
    Items.Add('Українська');  
  end;

  if ActiveLanguage='rus' then begin
    lang:= 'rus';
    ComboBox1.ItemIndex:= 0;
  end else
  if ActiveLanguage='eng' then begin
    lang:= 'eng';
    ComboBox1.ItemIndex:= 1;
  end else
  if ActiveLanguage='ukr' then begin
    lang:= 'ukr';
    ComboBox1.ItemIndex:= 2;
  end;
end;

[diman_21Ru]

nik1967, Вообще гуд

nik1967, А можно эту кнопку сделать более красивше ?

nik1967, И как можно размер изменить кнопки?

[nik1967]

А можно эту кнопку сделать более красивше ? »

Не понятно.

И как можно размер изменить кнопки? »

Можно изменить только ширину.