[Kopejkin]

erd-zelen, вам же говорят: сначала установите NSIS. Как вариант, после установки NSIS, попробуйте переустановить nisedit2.0.3 или сменить его версию на предыдущую.
На всякий случай: NSIS и nisedit2.0.3 - это не одно и то же

[erd-zelen]

вот теперь понятно! что надо переустановить. бывалым то понятно в чем глюк, а новичку поди разберись...

[alexfinik]

Друзья, взялся за свои инсталлятор после 5-тимесячного перерыва. Спасибо завсегдатаям за помощь огромное - он работает. Но хочу доработать, а всё забыл

Пока не разобрался с командой дико редко встречаемой (только у меня в комментариях???) ${OpenBox}

Команда из пакета Dialogs.nsh
Там есть стандартная программа,

Код:

!include "dialogs.nsh"

Name "OpenBox-1"
OutFile "OpenBox-1.exe"
XPStyle on
ShowInstDetails show

Function .onInit
# Params:
# 1) Title: "Search for a TEXT file"
# 2) Filter: "Text (*.txt)|*.txt||"
# 3) FilterIndex: 1
# 4) InitDir: $EXEDIR
# 5) Style: 3 (default style)
# 6) Return: $6
${OpenBox} "Search for a TEXT file" "Text (*.txt)|*.txt||" 1 "$EXEDIR" 3 ${VAR_6}
FunctionEnd

Section
# See if the user selects a file:
${if} $6 == "${NULL}"
DetailPrint "Operation was canceled!"
${else}
DetailPrint "You choose: $6"
${endif}
SectionEnd

Которая выдает ошибку при запуске

Код:

Processing script file: "D:\Desktop\examples\OpenBox-2.nsi"
!include: "C:\Program Files (x86)\NSIS\Unicode\Include\dialogs.nsh"
File 'C:\Program Files (x86)\NSIS\Unicode\Include\dialogs.nsh' has no BOM and does not validate as UTF-8.
!define: "DIALOGS_NSH"=""
!include: closed: "C:\Program Files (x86)\NSIS\Unicode\Include\dialogs.nsh"
Name: "OpenBox-2"
OutFile: "OpenBox-2.exe"
XPStyle: on
ShowInstDetails: show
Function: ".onInit"
Invalid command: dialogsEx::FileBox
Error in script "D:\Desktop\examples\OpenBox-2.nsi" on line 16 -- aborting creation process

Не понимаю что значит Invalid command: dialogsEx::FileBox
Интернет и форум молчит...

Спасибо.

[Flix]

Цитата Kopejkin:
но так... тоже не работает »
Тогда сделайте вот так:

читать дальше »

Код:

########## ПРИМЕР ##############

!define PRODUCT_NAME "FolderSizes 7"
!define PRODUCT_VERSION ".0.56"
!define BRANDING "PUPKIN"

SetCompressor /SOLID lzma

!include MUI.nsh
!include x64.nsh       ; поддержка 64-бит систем
!include Logiclib.nsh  ; расширенная поддержка логики

!define MUI_ABORTWARNING
!define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\modern-install.ico"
!define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall.ico"

!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_UNPAGE_FINISH

!insertmacro MUI_LANGUAGE "Russian"

Name "${PRODUCT_NAME}"
Caption "Установка русификатора ${PRODUCT_NAME}${PRODUCT_VERSION}"
UninstallCaption "Удаление русификатора ${PRODUCT_NAME}${PRODUCT_VERSION}"
OutFile "rus.${PRODUCT_NAME}${PRODUCT_VERSION}.exe"
InstallDir "$PROGRAMFILES\Key Metric Software\${PRODUCT_NAME}\"
RequestExecutionLevel admin
ShowInstDetails show
ShowUninstDetails show
BrandingText "${BRANDING}"

Function .onInit
  ${If} ${RunningX64}
     SetRegView 64
     StrCpy $INSTDIR "$PROGRAMFILES64\Key Metric Software\${PRODUCT_NAME}\"
  ${Else}
     MessageBox MB_OK|MB_ICONSTOP "Только для систем х64!" IDOK
     Quit
  ${EndIf}
FunctionEnd

Function un.onInit
  ${If} ${RunningX64}
     SetRegView 64
  ${EndIf}
FunctionEnd 

Section "-MainSection"

  SetOutPath "$INSTDIR"
  File /r "1.txt"
  WriteUninstaller "$INSTDIR\unrus.exe"
  ; блок Установка/Удаление программм
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "DisplayName" "${PRODUCT_NAME}${PRODUCT_VERSION}. Удалить русификатор"
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "UninstallString" "$INSTDIR\unrus.exe"
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "DisplayVersion" "1.0"
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "Publisher" "© Pupkin, 03/2014"
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "DisplayIcon" "$INSTDIR\unrus.exe"
  WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "NoModify" 0x00000001
  WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "NoRepair" 0x00000001

  SetShellVarContext all
  ; Ярлыки в меню Пуск - Программы
  CreateDirectory "$SMPROGRAMS\${PRODUCT_NAME}"
  ; в Win8 этот ярлык виден в ПРИЛОЖЕНИЯХ в ЛЮБОМ случае
  CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Открыть 1.txt.lnk" "$INSTDIR\1.txt" 
  ; в Win8 этот ярлык виден в ПРИЛОЖЕНИЯХ только при "ОТКЛЮЧЕНИИ" блока "Установка/Удаление"
  CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Удалить русификатор ${PRODUCT_NAME}.lnk" "$INSTDIR\unrus.exe"

  SetAutoClose false
SectionEnd

Section Uninstall
  Delete "$INSTDIR\1.txt"
  SetShellVarContext all
  Delete "$SMPROGRAMS\${PRODUCT_NAME}\Открыть 1.txt.lnk"
  Delete "$SMPROGRAMS\${PRODUCT_NAME}\Удалить русификатор ${PRODUCT_NAME}.lnk"
  DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus"
  delete "$INSTDIR\unrus.exe"
  SetAutoClose false
SectionEnd

Соберите инсталлятор по этому примеру и проверьте. У меня на виртуальной оси Windows 8.1 ярлык деинсталлятора исправно создается. Проверить на реальной системе нет возможности, но думаю там также должен создаваться. Если у вас и после этого не будет работать, то тогда я не знаю, больше ничем помочь не могу, идеи все закончились.

Не понимаю что значит Invalid command: dialogsEx::FileBox »

Не установлен плагин DialogsEx

[Kopejkin]

Flix, спасибо за терпение и советы.
Но.. не работает.
Тренируюсь тоже на виртуалке, причем специально установил 8.1 (до этого стояла 8).
Буду считать, что у других ярлык будет создаваться или откажусь от создания ярлыка в Установке/Удалении

[MKN]

Обновился AccessControl plug-in Version: 1.0.8.0 (24th March 2014)
http://nsis.sourceforge.net/AccessControl_plug-in

[Flix]

Но.. не работает. »

Kopejkin, озвученная вами проблема все таки имеет место на системах Windows 8/8.1. Установил на виртуалку второй системой Windows 8.1 64-бит. Запустил инсталлятор и... ярлыка деинсталляции на экране "Приложения" не обнаружил. Начал разбираться и выяснил вот что. Ярлык к файлу деинсталляции исправно создается, но Windows по неясным причинам, примерно через 10-15 секунд по завершении установки, в свойствах ярлыка самовольно меняет рабочий каталог файла деинсталляции. Первоначально там указан верный каталог, как и создал его инсталлятор (С:\Programs Files\...) но по истечении указанного промежутка времени путь волшебным образом меняется на С:\Programs Files (x86)\... В чем причина такого поведения системы - не знаю. Но побороть это можно установкой для файла ярлыка атрибута "только для чтения". Тогда Windows ничего не сможет сделать с ярлыком и он будет исправно отображаться на экране "Приложений". Вот сценарий, в котором добавлены соответствующие команды:

читать дальше »

Код:

########## ПРИМЕР ##############

!define PRODUCT_NAME "FolderSizes 7"
!define PRODUCT_VERSION ".0.56"
!define BRANDING "PUPKIN"

SetCompressor /SOLID lzma

!include MUI.nsh
!include x64.nsh       ; поддержка 64-бит систем
!include Logiclib.nsh  ; расширенная поддержка логики

!define MUI_ABORTWARNING
!define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\modern-install.ico"
!define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall.ico"

!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_UNPAGE_FINISH

!insertmacro MUI_LANGUAGE "Russian"

Name "${PRODUCT_NAME}"
Caption "Установка русификатора ${PRODUCT_NAME}${PRODUCT_VERSION}"
UninstallCaption "Удаление русификатора ${PRODUCT_NAME}${PRODUCT_VERSION}"
OutFile "rus.${PRODUCT_NAME}${PRODUCT_VERSION}.exe"
InstallDir "$PROGRAMFILES\Key Metric Software\${PRODUCT_NAME}\"
RequestExecutionLevel admin
ShowInstDetails show
ShowUninstDetails show
BrandingText "${BRANDING}"

Function .onInit
  ${If} ${RunningX64}
     SetRegView 64
     StrCpy $INSTDIR "$PROGRAMFILES64\Key Metric Software\${PRODUCT_NAME}\"
  ${Else}
     MessageBox MB_OK|MB_ICONSTOP "Только для х64!" IDOK
     Quit
  ${EndIf}
FunctionEnd

Function un.onInit
  ${If} ${RunningX64}
     SetRegView 64
  ${EndIf}
FunctionEnd 

Section "-MainSection"

  SetOutPath "$INSTDIR"
  File /r "1.txt"
  WriteUninstaller "$INSTDIR\unrus.exe"
  ; блок Установка/Удаление программм
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "DisplayName" "${PRODUCT_NAME}${PRODUCT_VERSION}. Удалить русификатор"
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "UninstallString" "$INSTDIR\unrus.exe"
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "DisplayVersion" "1.0"
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "Publisher" "© Pupkin, 03/2014"
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "DisplayIcon" "$INSTDIR\unrus.exe"
  WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "NoModify" 0x00000001
  WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus" "NoRepair" 0x00000001

  SetShellVarContext all
  ; Ярлыки в меню Пуск - Программы
  CreateDirectory "$SMPROGRAMS\${PRODUCT_NAME}"
  ; в Win8 этот ярлык виден в ПРИЛОЖЕНИЯХ в ЛЮБОМ случае
  CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Открыть 1.txt.lnk" "$INSTDIR\1.txt" 
  ; в Win8 этот ярлык виден в ПРИЛОЖЕНИЯХ только при "ОТКЛЮЧЕНИИ" блока "Установка/Удаление"
  CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Удалить русификатор ${PRODUCT_NAME}.lnk" "$INSTDIR\unrus.exe"

  ; Устанавливаем для ярлыка атрибут "только для чтения"
  SetFileAttributes "$SMPROGRAMS\${PRODUCT_NAME}\Удалить русификатор ${PRODUCT_NAME}.lnk" READONLY

  SetAutoClose false
SectionEnd

Section Uninstall
  Delete "$INSTDIR\1.txt"

  ; Снимаем с файла ярлыка атрибут "только для чтения", чтобы его можно было удалить
  SetFileAttributes "$SMPROGRAMS\${PRODUCT_NAME}\Удалить русификатор ${PRODUCT_NAME}.lnk" NORMAL

  SetShellVarContext all
  Delete "$SMPROGRAMS\${PRODUCT_NAME}\Открыть 1.txt.lnk"
  Delete "$SMPROGRAMS\${PRODUCT_NAME}\Удалить русификатор ${PRODUCT_NAME}.lnk"
  DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}rus"
  delete "$INSTDIR\unrus.exe"
  SetAutoClose false
SectionEnd

[wolkow70]

Ребята, у кого-нибудь получалось в NSIS создать ярлык сразу с правами администратора?

[MKN]

в NSIS создать ярлык сразу с правами администратора »

С помощью ShellLink plug-in http://nsis.sourceforge.net/ShellLink_plug-in
С помощью громозды из кода : http://nsis.sourceforge.net/IShellLink_Set_RunAs_flag
С помощью правки HEX в самом ярлыке (придётся править заранее, т.к. внятного NSIS кода для этого, пока нет... )
С помощью изменения данных в реестре для запуска конкретной программы (это не оч корректно, но можно... )

[wolkow70]

MKN,
Первые два варианта понравились. Работает.