[Limonica]

Для убидительности проверил и на SP3 (Windows XP Home Edition)
http://dropi.ru/qMy.jpg

Все образы с MSDN. Баг реально есть и именно на Home Edition.
ссылка на оригинальные образы http://yadi.sk/d/OOa1SUsk7oKs0

[MKN]

Ещё раз об определении архитектуры процессора. Был предложен плагин, но можно и так (когда то уже было...) :

Код:

OutFile "PROCESSOR_ARCHITECTURE.exe"
; Функция GetNativeSystemInfo получает информацию о текщей системе приложению, которое запущено под WOW64. 
; Если функция вызывается из 64-битного приложения, она эквивалентна функции GetSystemInfo.

Section
    ;System::Alloc 32 
    System::Alloc 36
    Pop $0 
    System::Call "Kernel32::GetNativeSystemInfo(i) v (r0)" 
    System::Call "*$0(&i2 .r1)" 
    System::Free $0 
     
    StrCmp $1 0 0 +2 
    MessageBox MB_OK "PROCESSOR_ARCHITECTURE :   INTEL "

    StrCmp $1 9 0 +2 
    MessageBox MB_OK "PROCESSOR_ARCHITECTURE :  AMD64"
       
    StrCmp $1 6 0 +2 
    MessageBox MB_OK "PROCESSOR_ARCHITECTURE : IA64 "
                   
    StrCmp $1 0xffff 0 +2 
    MessageBox MB_OK "PROCESSOR_ARCHITECTURE :  UNKNOWN "
SectionEnd

[Limonica]

kotkovets, когда ожидать фикс?

[kotkovets]

Баг реально есть и именно на Home Edition »

а именно в OSVERSIONINFOEX
неправильно возвращается значение, возвращаются в стек два значения: Professional и Home Edition с учетом этого факта
подправил winver2.nsh
p.s
исправлена работа в юникодной версии NSIS

[alexfinik]

Друзья, заколебался(( Не понимаю что делать(

Вот бесполезный код, собранный специально, чтобы посмотреть в каком порядке идет обработка кода. Мне нужно, чтобы при наличии окон в коде, у меня он обрабатывался последовательно. Т.е. сначала цикл 1, потом вложенный в него цикл 2, потом уже переходил к циклу 3 в следующей функции, у которой роль обрабатывать заданное в 1 и 2 цикле. В первом и втором цикле задаются массивы.

Помогите, пожалуйста, или направьте на нужную литературу, да хоть на английском. Может пойму...

Код:

!include nsDialogs.nsh
!include LogicLib.nsh

Name "nsDialogs Example"
OutFile "nsDialogs Example.exe"

XPStyle on

var Num1
var NumCash
var Dialog
var Label1
var Label2

Page custom test0 test1

Function test0
	MessageBox MB_OK "До цикла"
	
	
  ${ForEach} $R6 0 1 + 1
	nsDialogs::Create 1018
	Pop $Dialog
	${If} $Dialog == error
		Abort
	${EndIf}
	${NSD_CreateLabel} 0 0 100% 33u "окно цикла 1 $\n R6=$R6"
	Pop $Label1
	MessageBox MB_OK "Цикл1 $R6"
	StrCpy $Num1 $NumCash 
	nsDialogs::Show
	${ForEach} $R5 0 1 + 1
		nsDialogs::Create 1018
		Pop $Dialog
		${If} $Dialog == error
			Abort
		${EndIf}
		${NSD_CreateLabel} 0 0 100% 33u "окно цикла 2 $\n R5=$R5"
		Pop $Label2
		MessageBox MB_OK "Цикл2 $R5"
		nsDialogs::Show
	${Next}
${Next}
FunctionEnd

Function test1
${ForEach} $R7 0 1 + 1
	MessageBox MB_OK "Цикл3 $R7"
${Next}	
FunctionEnd


Section
SectionEnd

[kotkovets]

Может пойму... »

1. Зачем создавать множественный диалог nsDialogs::Create 1018 достаточно один раз создать диалог
2. В созданном диалоге разрушать, скрывать или создавать в цикле дочерние элементы диалога..
3. Функция test1 выполняется при закрытии (выполнении) функции test0

[Limonica]

kotkovets, огромное человеческое спасибо!

[MKN]

Разнообразные параметры ОС (версия, Build, SP и пр. )можно определить и с помощью WMI хедера.
Например :

Код:

;http://nsis.sourceforge.net/WMI_header
OutFile "OperatingSystemInfo.exe"
!include MUI2.nsh
!include WMI.nsh
!include LogicLib.nsh
!insertmacro MUI_LANGUAGE "English"

Section 
; короткое описание версии операционной системы
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem Caption callback_Function
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem Version callback_Function
; последний установленный сервис-пак (строка); если никакой сервис-пак не установлен, пустая строка.
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem CSDVersion callback_Function
; версия сервис-пака
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem ServicePackMajorVersion callback_Function
; подверсия сервис-пака
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem ServicePackMinorVersion callback_Function
; Processor Type
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem BuildType callback_Function
; имя компьютера
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem CSName callback_Function
; зарегистрированный пользователь операционной системы
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem RegisteredUser callback_Function
; идентификатор языка, используемого операционной системой
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem Locale callback_Function
; OSLanguage
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem OSLanguage callback_Function
; тип операционной системы:
;  16 - WIN95, 17 - WIN98, 18 - WINNT, 19 - WINCE
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem OSType callback_Function
SectionEnd
 
Function callback_Function
#$R0 = result number, $R1 = total results, $R2 = result name
System::Call "user32::OemToChar(t R2, t. r2)"
detailprint "$2" 
FunctionEnd

Но есть такой вопрос - как распределить полученные данные раздельно по разным переменным ?

[K.A.V.]

Но есть такой вопрос - как распределить полученные данные раздельно по разным переменным ? »

Элементарно

Код:

Var WMI_Caption
Var WMI_Version
Var WMI_CSDVersion
Var WMI_ServicePackMajorVersion
Var WMI_ServicePackMinorVersion
Var WMI_BuildType
Var WMI_CSName
Var WMI_RegisteredUser
Var WMI_Locale
Var WMI_OSLanguage
Var WMI_OSType
Var WMI_PushVar

;http://nsis.sourceforge.net/WMI_header
OutFile "OperatingSystemInfo.exe"
!include MUI2.nsh
!include WMI.nsh
!include LogicLib.nsh
!insertmacro MUI_LANGUAGE "English"



Section 

; короткое описание версии операционной системы
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem Caption callback_Function
 StrCpy $WMI_Caption $WMI_PushVar

${WMIGetInfo} root\CIMV2 Win32_OperatingSystem Version callback_Function
 StrCpy $WMI_Version $WMI_PushVar

; последний установленный сервис-пак (строка); если никакой сервис-пак не установлен, пустая строка.
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem CSDVersion callback_Function
 StrCpy $WMI_CSDVersion $WMI_PushVar

; версия сервис-пака
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem ServicePackMajorVersion callback_Function
 StrCpy $WMI_ServicePackMajorVersion $WMI_PushVar

; подверсия сервис-пака
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem ServicePackMinorVersion callback_Function
 StrCpy $WMI_ServicePackMinorVersion $WMI_PushVar

; Processor Type
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem BuildType callback_Function
 StrCpy $WMI_BuildType $WMI_PushVar

; имя компьютера
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem CSName callback_Function
 StrCpy $WMI_CSName $WMI_PushVar

; зарегистрированный пользователь операционной системы
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem RegisteredUser callback_Function
 StrCpy $WMI_RegisteredUser $WMI_PushVar

; идентификатор языка, используемого операционной системой
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem Locale callback_Function
 StrCpy $WMI_Locale $WMI_PushVar

; OSLanguage
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem OSLanguage callback_Function
 StrCpy $WMI_OSLanguage $WMI_PushVar
             
; тип операционной системы:
;  16 - WIN95, 17 - WIN98, 18 - WINNT, 19 - WINCE
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem OSType callback_Function
  StrCpy $WMI_OSType $WMI_PushVar



###################################################
FileOpen $0 "$EXEDIR\WMI.txt" w
FileWrite $0 "=== OperatingSystemInfo.exe ===$\n"
FileWrite $0 "$\n$$WMI_Caption = $WMI_Caption"
FileWrite $0 "$\n$$WMI_Version = $WMI_Version"
FileWrite $0 "$\n$$WMI_CSDVersion = $WMI_CSDVersion"
FileWrite $0 "$\n$$WMI_ServicePackMajorVersion = $WMI_ServicePackMajorVersion"
FileWrite $0 "$\n$$WMI_ServicePackMinorVersion = $WMI_ServicePackMinorVersion"
FileWrite $0 "$\n$$WMI_BuildType = $WMI_BuildType"
FileWrite $0 "$\n$$WMI_CSName = $WMI_CSName"
FileWrite $0 "$\n$$WMI_RegisteredUser = $WMI_RegisteredUser"
FileWrite $0 "$\n$$WMI_Locale = $WMI_Locale"
FileWrite $0 "$\n$$WMI_OSLanguage = $WMI_OSLanguage"
FileWrite $0 "$\n$$WMI_OSType = $WMI_OSType"
FileClose $0
execshell open "$EXEDIR\WMI.txt"
  
 quit
###################################################
SectionEnd
 
Function callback_Function
#$R0 = result number, $R1 = total results, $R2 = result name
System::Call "user32::OemToChar(t R2, t. r2)"
detailprint "$2"
StrCpy $WMI_PushVar $2 
FunctionEnd

[kotkovets]

MKN

Разнообразные параметры ОС (версия, Build, SP и пр. )можно определить и с помощью WMI

в моем winver2 так и сделано...
точнее гибридно..