[решено] Как сделать,что б батник проверял число ?

ShaddyR · Конфигурация компьютера

nj_: озвучу, раз аналогия не понята

Код:

set file=%SYSTEMROOT%\setupact.log
If Exist %file% For %%i In (%file%) Do SET TIMESTAMP=%%~ti
echo %timestamp%

nj_ · Отправлено: **22:58, 15-09-2006** | #12

Провтикал аналогию

Спасибо!

Ешо один глупий вопрос:
как присвоит переменной значение дати на n дней (месяцев) больше (меньше) текущей?

ShaddyR · Конфигурация компьютера

nj_

Цитата:

как присвоит переменной значение дати на n дней (месяцев) больше (меньше) текущей?

я честно попытался решить этот вопрос... с учетом отсутствия в коммандном процессоре мат. операций. Все, что я нашел - это вот эта лабораторная работа, в которой среди прочего делается

Цитата:

Написание командного скрипта для вывода ряда фибоначи (т.е. где каждый последующий член ряда равен сумме двух предыдущих: 1, 1, 2, 3, 5, 8, 13, ...). Для этого будет использовано несколько пакетных файлов, работа с переменными окружения и тд.

Пару раз его перечитал и понял, шо я ничего не понял. Попробуй, мож у тебя лучше получится

DarkTiger · Отправлено: **15:39, 18-10-2006** | #14

Эммммм ребят, сори за офтоп, кто нибудь может поделиться своими источниками (будь то название книги, сылка на электронное издание, какие то статьи в инете и пр.) по написанию bat файлов. А то через поисковик ничего дельного не нашёл. Заранее спасибо за ответ

Sanja Alone · Конфигурация компьютера

DarkTiger

Цитата:

поделиться своими источниками

Когда-то давно учился этому делу по книге Питера Нортона "MS-DOS" (точного названия не помню; помню, что в мягкой зеленой обложке была). Недавно обновил знания просто почитав C:\WINDOWS\Help\ntcmds.chm

amel27 · Отправлено: **13:16, 19-10-2006** | #16

ShaddyR

Цитата:

с учетом отсутствия в коммандном процессоре мат. операций.

ты не прав - все календарные расчеты основаны на целочисленной арифметике, так что возможностей командного процессора за глаза хватает, хотя алгоритмы действительно нельзя назвать простыми - в языках высокого уровня они скрыты за функциями преобразования времени. Как-то хотел сделать расчет одной похожей задачки на CMD, но время поджимало и пришлось делать на VBS... если соберусь, то попробую переделать...

DarkTiger
из "избранного":
http://www.windowsfaq.ru/content/category/3/7/45
http://www.windowsfaq.ru/content/category/3/19/57/
http://www.microsoft.com/technet/pro.../FAQW2KCP.mspx
http://www.robvanderwoude.com/index.html

DarkTiger · Отправлено: **18:30, 19-10-2006** | #17

amel27 Огромное спасибо, уже читаю, написано на доступном языке, кроме последних 2 сылок, потому как англиский знаю плохо

amel27 · Отправлено: **05:51, 20-10-2006** | #18

Цитата:

как присвоит переменной значение дати на n дней (месяцев) больше (меньше) текущей?

Самый простой способ (и самый медленный) - итеративный цикл по количеству дней... Как и предупреждал, несколькими строчками кода не обошлось. Для ускорения расчетов можно было применить цикл по месяцам с выравниванием даты на последнем шаге, но тогда код стал бы еще более громоздким и плохо читаемым.

Код:

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
Rem Параметры расчета: кол-во дней (>0!) и направление (+/-)
SET DAYS=730
SET SIGN=+
Rem Установка окружения и цикл расчета
CALL :GetDate
CALL :GetMnthDays
:Start
CALL :NextDay "%SIGN%1"
SET /A DAYS=%DAYS%-1
IF %DAYS% NEQ 0 GOTO :Start
Rem Вывод результата и завершение работы
CALL :ShowDate
EXIT
Rem Перемещение на следующий/предыдущий календарный день
:NextDay
SET /A Day=%Day%%~1
IF %Day% GTR !DOFW! (
	CALL :NextMonth +1
	CALL :GetMnthDays
	SET /A Day=1
)
IF %Day% EQU 0 (
	CALL :NextMonth -1
	CALL :GetMnthDays
	SET /A Day=!DOFW!
)
GOTO :EOF
Rem Расчет года и месяца, отстоящих от заданного
:NextMonth
SET /A MNDF=%Year%*12+%Month%%1
SET /A Year=(%MNDF%-1)/12
SET /A Month=%MNDF%-%Year%*12
GOTO :EOF
Rem Число дней в заданном месяце
:GetMnthDays
IF %Month% EQU 2 (
	CALL :IsYearVisok
	SET /A DOFW = 28+!VISOK!
) ELSE (
	SET NUM=0
	FOR %%i IN (31 28 31 30 31 30 31 31 30 31 30 31) DO (
		SET /A NUM=!NUM!+1
		IF %Month% EQU !NUM! (
			SET DOFW=%%i
			GOTO :EOF
		)
	)
)
GOTO :EOF
Rem Проверка года на високосность
:IsYearVisok
SET /A M1=%Year%-(%Year%/4)*4
SET /A M2=%Year%-(%Year%/100)*100
SET /A M3=%Year%-(%Year%/400)*400

SET VISOK=0
IF 0 EQU %M1% IF 0 NEQ %M2% SET VISOK=1
IF 0 EQU %M3% SET VISOK=1
GOTO :EOF
Rem Чтение текущей даты в переменные окружения
:GetDate
FOR /F "tokens=1,3" %%i IN ('REG QUERY "HKCU\Control Panel\International" /s^|findstr /C:"iDate" /C:"sDate"') DO SET %%i=%%j
FOR /F "TOKENS=1-4* DELIMS=%sDate% " %%A IN ('DATE/T') DO (
	IF %iDate%==0 (
		SET Year=%%C
		SET Month=%%A
		SET Day=%%B
	)
	IF %iDate%==1 (
		SET Year=%%C
		SET Month=%%B
		SET Day=%%A
	)
	IF %iDate%==2 (
		SET Year=%%A
		SET Month=%%B
		SET Day=%%C
	)
)
GOTO :EOF
Rem Отображение итоговой даты
:ShowDate
SET Month=0%Month%
SET Month=%Month:~-2%
SET Day=0%Day%
SET Day=%Day:~-2%
IF %iDate%==0 ECHO %Month%%sDate%%Day%%sDate%%Year%
IF %iDate%==1 ECHO %Day%%sDate%%Month%%sDate%%Year%
IF %iDate%==2 ECHO %Year%%sDate%%Month%%sDate%%Day%
GOTO :EOF

ShaddyR · Конфигурация компьютера

amel27: силён!

Sanja Alone · Конфигурация компьютера

Немного дополнил ф-цию получения текущей даты из поста 18. Дополнение связано с различием в отображении даты в зависимости от sLongDate и sShortDate. Я обошелся без необходимости проверки этих параметров в реестре, а поступил проще (правда, понадобилась лишняя переменная).

Код:

Rem Чтение текущей даты в переменные окружения
:GetDate
for /f "tokens=1,3" %%j in ('reg query "HKCU\Control Panel\International" /s^|findstr /C:"iDate" /C:"sDate"') do set %%j=%%k
for /f %%j in ('echo %date%^|find " " /C') do (
	if %%j == 1 (
		for /f "tokens=2 delims= " %%j in ('echo %date%') do set mdate=%%j
	) else (
		set mdate=%date%
	)
)
for /f "tokens=1,2,3 delims=%sDate%" %%j in ('echo %mdate%') do (
	if %iDate%==0 (
		set Month=%%j
		set Day=%%k
		set Year=%%l
	)
	if %iDate%==1 (
		set Day=%%j
		set Month=%%k
		set Year=%%l
	)
	if %iDate%==2 (
		set Year=%%j
		set Month=%%k
		set Day=%%l
	)
)
goto :EOF

Да, совсем забыл. Вот ф-ция для установки даты:

Код:

Rem Установка даты
:SetDate
if %iDate%==0 (
	date %Month%%sDate%%Day%%sDate%%Year%
) else (
	if %iDate%==1 (
		date %Day%%sDate%%Month%%sDate%%Year%
	) else (
		if %iDate%==2 (
			date %Year%%sDate%%Month%%sDate%%Day%
		)
	)
)
goto :EOF

Ситуация, в к-рой могут пригодиться приведенные выше ф-ции:

Код:

Rem Определение текущей даты
call :GetDate
Rem прибавление 1 года к дате
set /a Year+=1
Rem Установка даты
call :SetDate

Rem Выполнение определенных манипуляций

Rem Возврат реальной даты (отнимаем 1 год)
set /a Year-=1
Rem Установка даты
call :SetDate