[Iska]

Надо полагать, его нет у Вас в списке форматов. Насколько я понимаю, перед тем, как использовать пользовательский тип формата в .FindFormat/.ReplaceFormat — его нужно добавить к списку пользовательских форматов. Т.е., что-то наподобие:

Код:

Option Explicit

Sub Макрос1()
    ActiveSheet.Range("D1").NumberFormat = "dd-mm-yyyy"
    
    With Application
        With .FindFormat
            .Clear
            .NumberFormat = "m/d/yyyy"
        End With
        
        With .ReplaceFormat
            .Clear
            .NumberFormat = "dd-mm-yyyy"
        End With
    End With
    
    ActiveSheet.Cells.Replace What:="", Replacement:="", SearchFormat:=True, ReplaceFormat:=True
    
    ActiveSheet.Range("D1").NumberFormat = "General"
End Sub

поскольку единственным известным мне способом программного добавления является применение формата к ячейке листа рабочей книги. В примере была взята некая пустая ячейка, отформатирована потребным форматом, сделан поиск и замена, затем эта же пустая ячейка приведена к формату по умолчанию.

[kontox]

Iska,

вот для примера набор данных. Взял из головы столбец A это id B-фио С номер кейса D-состояние E номер телефона как можно сделать чтобы отобразились те данные, где в столбце А тип number (4) в столбце B тип varchar(20 char) в столбце С тип varchar(12 char) В столбце D тип number(1) в столбце E тип number(11) Вложения »

что-то код написан, а не работает. Можете посмотреть, где в нем ошибка?

[Iska]

что-то код написан, а не работает. Можете посмотреть, где в нем ошибка? »

Что значит «не работает»? А как должен был работать?

Ваших потребностей я не понял, о чём писал уже выше. Других пояснений Вы не дали.

[kontox]

Исходя из описанного ниже формата нужно выделить только корректные записи, т.е. записи такого вида.
Название поля Тип (длина) Обязательность
1 ID number (4) NOT NULL
2 FIO varchar (20 char ) NOT NULL
3 Document varchar (12 char NOT NULL
4 Type_phone number (1) NULL
5 Phone number (11) NULL

[Iska]

kontox, что означает, например, «длина (4)» применительно к «number»? Число десятичных символов при отображении?!

Update: и по поводу:

4 Type_phone number (1) NULL 5 Phone number (11) NULL

как понимать — должны быть пустыми? Или могут быть пустыми?

В общем, как-то так:

Скрытый текст

Код:

Sub Sample()
    Dim objRow As Range
    Dim objRange As Range
    Dim objSelection As Range
    
    Dim boolSkipFromSelection As Boolean
    
    
    Set objSelection = Nothing
    
    For Each objRow In ThisWorkbook.Worksheets.Item("proverka").UsedRange.Rows
        boolSkipFromSelection = False
        
        For Each objRange In objRow.Range(Cells(1, 1), Cells(1, 3)).Cells
            If IsEmpty(objRange.Value) Then
                boolSkipFromSelection = True
                
                Exit For
            End If
        Next
        
        If Len(CStr(objRow.Cells(1, 1).Value)) > 4 Then
            boolSkipFromSelection = True
        ElseIf Len(CStr(objRow.Cells(1, 2).Value)) > 20 Then
            boolSkipFromSelection = True
        ElseIf Len(CStr(objRow.Cells(1, 3).Value)) > 12 Then
            boolSkipFromSelection = True
        ElseIf Len(CStr(objRow.Cells(1, 4).Value)) > 1 Then
            boolSkipFromSelection = True
        ElseIf Len(CStr(objRow.Cells(1, 5).Value)) > 11 Then
            boolSkipFromSelection = True
        End If
        
        If Not boolSkipFromSelection Then
            If objSelection Is Nothing Then
                Set objSelection = objRow
            Else
                Set objSelection = Union(objSelection, objRow)
            End If
        End If
    Next
    
    objSelection.Select
    
    Set objSelection = Nothing
    Set objRange = Nothing
    Set objRow = Nothing
End Sub